' Nokia BD58 radion ohjaus PC:n LPT1-portin kautta
' Arto Harjula, OH2BGN/6GJ, 16.10.1994
'
' LPT portin D-25 siltaus: 11,12 - GND, 14 - +V (15)
' D-25:  2  3   4   5   6  18
' D-37: 20  1  23  21  22  7

nolla% = 0: SRE% = 4: STE% = 8: SCE% = 16
offset = 0: alku = 0
DIM tavu%(30): ff% = 255

'INPUT "rx,tx", Frx, Ftx
Frx = 50800: Ftx = 55225:
Dev = 8 'deviaatio 0...15
Imf = 45000 ' kHz v„litaajuus 86.5125 21.4 tai 45
esijakaja = 64
kanvali = 12.5 'kHz

GOSUB kanava
END

kanava: 'muunnetaan ja asetetaan yhden kanavan tiedot
        ' IF = 86,5125 MHz:  esijakaja P=128
        ' IF = 45 MHz:  esijakaja P=64
                         
        RN = INT((Frx + Imf) / (esijakaja * kanvali))
        RA% = (Frx + Imf) / kanvali - RN * esijakaja
        TN = INT(Ftx / esijakaja / kanvali)
        TA% = Ftx / kanvali - TN * esijakaja

        R% = 12800 / kanvali

        LPRINT CHR$(nolla%);

        ctl% = Dev * 16 + 8: GOSUB kontr
        A% = RA%: N = RN: ena% = SRE%: GOSUB jako
        A% = TA%: N = TN: ena% = STE%: GOSUB jako
RETURN

jako: 'jakolukujen lataus
        CR% = R% * 2 + 1
        Fvco = (A% + N * 64) * 12.5
        PRINT Fvco,

        L = 15: x = CR%: GOSUB tul   'ref.jakaja R
        GOSUB lataa                  'load
        L = 10: x = N: GOSUB tul     'N jakaja
        L = 8: x = A% * 2: GOSUB tul 'A jakaja
        GOSUB lataa                  'load
RETURN

kontr: ' controllitavun lataus
       ' PRINT ctl%
        L = 8: x = ctl%: GOSUB tul
        ena% = SCE%: GOSUB lataa
RETURN

tul: 'L tavun muotoilu ja tulostus
        FOR i = 1 TO L
                tavu%(L + 1 - i) = 2 * (x MOD 2)
                x = INT(x / 2)
        NEXT i
        FOR i = 1 TO L
                'PRINT tavu%(i);
                LPRINT CHR$(tavu%(i));
                tavu2% = tavu%(i) + 1
                LPRINT CHR$(tavu2%);
        NEXT i
RETURN

lataa:          'v„li ja lataus rekisteriin enable-pulssilla
        LPRINT CHR$(nolla%);
        LPRINT CHR$(ena%);
        LPRINT CHR$(nolla%);
        PRINT ena%
RETURN